Setting up your Label Templates

Written by Jasmine O

Last published at: April 24th, 2024
Delete

Info

To set your label templates, please contact our Support team 


ZPL Sample Label Template 

Sample Label Template (51mm x 25mm)

This template is designed for:

  • Label size: 51mm x 25mm
  • Label type: normal
  • Density : 203 DPI, 8 dpmm
  • Printer ?
  • Font used :  D


Click for Template 

^XA


^FX --- Print Orientation (POI = inverted, PON = normal) ^FS
^PON


^FX --- Fixed Media Darkness: 25 ^FS
~SD25


^FX --- Page Offset (x, y) ^FS
^LH10,0
^LT0


^FX --- Page Size: 51mm x 25mm, gapped media @ 203DPI, 8 dpmm ^FS
^PW406




^FX --- LM Logo White text/black background (printed) ^FS
^FO0,0^GB25,406,20^FS
^FO5,5^ADB,20,^FR^FB198,1,0,C,0^FDLAUNCHMETRICS\&^FS


^FX --- Printing Speed: 4 ^FS
^PR4,4,4


^FX --- Charset: UTF-8 ^FS
^CI28


^FX --- Media Type: Thermal Transfer (questionable) ^FS
^MTT


^FO25,12^ADN,23^FB381,1,0,C,9999^FD%department%\&^FS
^FO25,29^ADN,16,^FB381,1,0,C,9999^FD%department_telephone%\&^FS


^FX --- Sample Barcode ^FS
^BY2,3,40^FT70,90^BCN,40,N^FD>:%barcode%^FS
^FO25,95^ADN,14,^FB381,1,0,C,9999^FD%barcode%\&^FS


^FO30,115^ADN,21,^FB376,7,0,L^FD%automatic_wrapping_layout_preferences_line%
^FS




^FX --- Print Quantity (Always 1 for address labels) ^FS
^PQ%number_of_copies%


^XZ
Delete

Also for the instructions you can use:

Use %wrapped_layout_preferences% or %automatic_wrapping_layout_prefrences_line% in your label template to populate Sample data. The fields you indicate above will display continuously unless you include a line break, dash or comma within your layout preferences.

Barcode Printing via Address Label Printer 

This template is designed for:

  • Label size:  50.8mm x 25.4mm
  • Label type: normal 
  • Label Model: 880247-025D
  • Printer: GK420D


Click for Template

Q203,018
q448
rN
S3
D15
ZT
JF
O
R200,0
N
A110,1,0,2,1,1,N,"%department%"
A130,18,0,2,1,1,N,"%department_telephone%"
B90,35,0,1,2,6,43,N,"%barcode%"
A130,81,0,2,1,1,N,"%barcode%"
A35,98,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,115,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,131,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,147,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,164,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,180,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A15,170,3,2,1,1,R,"LAUNCHMETRICS"
P%number_of_copies%

Delete


Barcode Printing via TLP2824

This template is designed for:

  • Label size:  50.8mm x 25.4mm
  • Label type: normal 
  • Label Model: 880247-025D
  • Notes: No ink resin 
  • Printer: TLP2824


Click for Template

Q203,018
q448
rN
S3
D15
ZT
JF
O
R3,0
N
A80,1,0,2,1,1,N,"%department%"
A130,18,0,2,1,1,N,"%department_telephone%"
B90,35,0,1,2,6,43,N,"%barcode%"
A130,81,0,2,1,1,N,"%barcode%"
A35,98,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,115,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,131,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,147,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,164,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A35,180,0,2,1,1,N,"%wrapped_layout_preferences_line%"
A15,170,3,2,1,1,R,"LAUNCHMETRICS"
P%number_of_copies%

Delete


Barcode Printing via ZD421D (Direct Thermal)

This template is designed for:

  • Label size:  50.8mm x 25.4mm
  • Label type: normal 
  • Label Model:  880247-025D
  • Notes: Ink required (Zebra 05095GS06407 64mm x 74m)
  • Printer: ZD421D


Click for Template

Q203,018
q250
rN
S3
D15
ZT
JF
O
R220,0
N
A35,1,0,1,1,1,N,"%department%"
A60,18,0,1,1,1,N,"%department_telephone%"
B50,35,0,1,2,6,43,N,"%barcode%"
A130,81,0,2,1,1,N,"%barcode%"
A35,98,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A35,115,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A35,131,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A35,147,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A35,164,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A35,180,0,1,1,1,N,"%wrapped_layout_preferences_line%"
A15,170,3,2,1,1,R,"LAUNCHMETRICS"
P%number_of_copies%

Delete


Barcode Printing via ZD410 

This template is designed for:

  • Label size: 38.1X25.4
  • DPI: 203
  • Label type: normal 
  • Label Model: 800261-107
  • Notes: No ink required
  • Printer: ZD410


Click for Template

^XA

^FX --- Print Orientation (POI = inverted, PON = normal) ^FS
^PON

^FX --- Fixed Media Darkness: 25 ^FS
~SD25

^FX --- Page Offset (x, y) ^FS
^LH8,8
^LT0

^FX --- Page Size: 38.1mm x 25.4mm, gapped media @ 203DPI, 8 dpmm ^FS
^PW303

^FX --- LM Logo White text/black background (printed) (thinner than usual) ^FS
^FO0,0^GB303,10,20^FS
^FO0,3^ADN,20,^FR^FB303,1,0,C,0^FDLAUNCHMETRICS\&^FS

^FX --- Printing Speed: 4 ^FS
^PR4,4,4

^FX --- Charset: UTF-8 ^FS
^CI28

^FX --- Media Type: Thermal Transfer (questionable) ^FS
^MTT

^FO5,27^ADN,23^FB303,1,0,C,9999^FD%department%\&^FS
^FO5,44^ADN,16,^FB303,1,0,C,9999^FD%department_telephone%\&^FS

^FX --- Sample Barcode ^FS
^BY2,3,40^FT7,105^BCN,40,N^FD>:%barcode%^FS
^FO5,110^ADN,14,^FB303,1,0,C,9999^FD%barcode%\&^FS

^FO10,130^ADN,21,^FB293,4,0,L^FD%wrapped_layout_preferences_block%^FS


^FX --- Print Quantity (Always 1 for address labels) ^FS
^PQ%number_of_copies%

^XZ

Delete



Sample RFID Label Template (44mm x 24mm)

This template is designed for:

  • Label size: 44mm x 24mm
  • Label type: RFID
  • Printer: ZD621R 


Click for Template

^XA
^FX --- Page Offset (x, y) ^FS
^LH0,40


^FX --- Media Darkness Level: 20 ^FS
~SD10


^FX --- Page Size: 44mm x 24mm, non continous media ^FS
^PW190


^FX --- Printing Speed: 2 ^FS
^PR2,2,2


^FX --- Charset: UTF-8 ^FS
^CI28


^FX --- Media Type: Thermal Transfer ^FS
^MTT


^FX --- LM Logo White text/black background (printed) ^FS
^FO170,2^GB20,350,20^FS
^FO168,5^FR^A@R,20,,TT0003M_.TTF^FB345,1,0,C^FDLAUNCHMETRICS^FS


^FX --- Label Boundaries (44mm x 24mm) (remove in production after calibration) ^FS
^FX --- At 203 DPI (8 dpmm) width = (44*8)-2; ^FS
^FX --- At 203 DPI (8 dpmm) height = (24*8)-2 ^FS
^FO0,0^GB190,350,1^FS


^FX --- Select font to use for all following lines ^FS
^FO0,20^A@N,12,,TT0003M_.TTF^FD^FS


^FX --- Barcode Lines (barcode) ^FS
^BY2,2,40^FT125,30^BCR,,N^FD>:%barcode%^FS


^FX --- Barcode Text (barcode) ^FS
^FO100,0^A@R,20^FB348,1,0,C^FD%barcode%^FS


^FX --- EAN-13 Centered (external_sku) ^FS
^FO78,0^A@R,20^FB348,1,0,C^FD%external_sku%^FS


^FX --- Specific Layout, centered (wrap up to 2 lines) ^FS
^FX --- Caveat with vertical labels is that we have to determine the bottom-left corner of the text box, rotated 90deg ^FS
^FO34,0^A@R,20^FB348,2,2,C^FD%style_number% %fabric% %color% %size%^FS




^FX --- Symbol Description (custom7), centered ^FS
^FO2,0^A@R,32^FB348,1,0,C^FD%custom7%^FS


^FX --- Symbol Image (custom8), right aligned ^FS
^FO0,0^A@R,54^FB324,1,0,R^FD%custom8%^FS


^FX --- RFID Read Configuration ^FS
^RW27,27
^RS8,,190,1,N
^FN1^RFR,H,2,12,1^FS
^HV1,24,[,],^FS


^FX --- Dynamic Print Quantity ^FS
^PQ%number_of_copies%,0,1,Y
^XZ
Delete


How do you calculate the correct value of the ^PW parameter ? 

Take the label width measurement in mm and multiply by 8 (for 203 DPI printers), or multiply by 12 (for 300 DPI printers) then substract 2 from that result. 

A good resource to test this on is Labelary Online ZPL Viewer, where you can specify the label size in mm.

Choose the print density 12 dpmm (300 dpi) / 8 dpmm (203 DPI) and then paste your label ZPL code. On the right side the linter error may give you a warming if you go above the maximum possible.